legitimate development, data science, and ai/ml workflows where authorized developers, researchers, or engineers intentionally execute local llm frameworks (ollama, lm studio, gpt4all, jan, nutstudio) for model experimentation, fine-tuning, or prototyping. python developers using huggingface transformers or langchain for legitimate ai/ml projects. approved sandbox and lab environments where framework testing is authorized. open-source contributors and hobbyists running frameworks for educational purposes. third-party applications that bundle or invoke llm frameworks as dependencies (e.g., ide plugins, analytics tools, chatbot integrations). system administrators deploying frameworks as part of containerized services or orchestrated ml workloads. process name keyword overlap with unrelated utilities (e.g., \"llama-backup\", \"janimation\"). recommended tuning — baseline approved frameworks and users by role/department, exclude sanctioned dev/lab systems via the filter macro, correlate with user identity and peer group anomalies before escalating to incident response.

Techniques

T1543

Sample rules

Windows Local LLM Framework Execution

source: splunk
technicques:
- T1543

Description

The following analytic detects execution of unauthorized local LLM frameworks (Ollama, LM Studio, GPT4All, Jan, llama.cpp, KoboldCPP, Oobabooga, NutStudio) and Python-based AI/ML libraries (HuggingFace Transformers, LangChain) on Windows endpoints by leveraging process creation events. It identifies cases where known LLM framework executables are launched or command-line arguments reference AI/ML libraries. This activity is significant as it may indicate shadow AI deployments, unauthorized model inference operations, or potential data exfiltration through local AI systems. If confirmed malicious, this could lead to unauthorized access to sensitive data, intellectual property theft, or circumvention of organizational AI governance policies.

Detection logic


| tstats `security_content_summariesonly` count
    min(_time) as firstTime
    max(_time) as lastTime
from datamodel=Endpoint.Processes
where
    (
      Processes.process_name IN (
          "gpt4all.exe",
          "jan.exe",
          "kobold.exe",
          "koboldcpp.exe",
          "llama-run.exe",
          "llama.cpp.exe",
          "lmstudio.exe",
          "nutstudio.exe",
          "ollama.exe",
          "oobabooga.exe",
          "text-generation-webui.exe"
      )
      OR
      Processes.original_file_name IN (
          "ollama.exe",
          "lmstudio.exe",
          "gpt4all.exe",
          "jan.exe",
          "llama-run.exe",
          "koboldcpp.exe",
          "nutstudio.exe"
      )
      OR
      Processes.process IN (
          "*\\gpt4all\\*",
          "*\\jan\\*",
          "*\\koboldcpp\\*",
          "*\\llama.cpp\\*",
          "*\\lmstudio\\*",
          "*\\nutstudio\\*",
          "*\\ollama\\*",
          "*\\oobabooga\\*",
          "*huggingface*",
          "*langchain*",
          "*llama-run*",
          "*transformers*"
      )
      OR
      Processes.parent_process_name IN (
          "gpt4all.exe",
          "jan.exe",
          "kobold.exe",
          "koboldcpp.exe",
          "llama-run.exe",
          "llama.cpp.exe",
          "lmstudio.exe",
          "nutstudio.exe",
          "ollama.exe",
          "oobabooga.exe",
          "text-generation-webui.exe"
      )
    )
by Processes.action Processes.dest Processes.original_file_name Processes.parent_process
   Processes.parent_process_exec Processes.parent_process_guid Processes.parent_process_id
   Processes.parent_process_name Processes.parent_process_path Processes.process
   Processes.process_exec Processes.process_guid Processes.process_hash Processes.process_id
   Processes.process_integrity_level Processes.process_name Processes.process_path Processes.user
   Processes.user_id Processes.vendor_product

| `drop_dm_object_name(Processes)`

| eval Framework=case(
    match(process_name, "(?i)ollama") OR match(process, "(?i)ollama"), "Ollama",
    match(process_name, "(?i)lmstudio") OR match(process, "(?i)lmstudio") OR match(process, "(?i)lm-studio"), "LM Studio",
    match(process_name, "(?i)gpt4all") OR match(process, "(?i)gpt4all"), "GPT4All",
    match(process_name, "(?i)kobold") OR match(process, "(?i)kobold"), "KoboldCPP",
    match(process_name, "(?i)jan") OR match(process, "(?i)jan"), "Jan AI",
    match(process_name, "(?i)nutstudio") OR match(process, "(?i)nutstudio"), "NutStudio",
    match(process_name, "(?i)llama") OR match(process, "(?i)llama"), "llama.cpp",
    match(process_name, "(?i)oobabooga") OR match(process, "(?i)oobabooga") OR match(process, "(?i)text-generation-webui"), "Oobabooga",
    match(process, "(?i)transformers") OR match(process, "(?i)huggingface"), "HuggingFace/Transformers",
    match(process, "(?i)langchain"), "LangChain",
    1=1, "Other"
)

| `security_content_ctime(firstTime)`

| `security_content_ctime(lastTime)`

| table action dest Framework original_file_name parent_process parent_process_exec
        parent_process_guid parent_process_id parent_process_name parent_process_path
        process process_exec process_guid process_hash process_id process_integrity_level
        process_name process_path user user_id vendor_product

| `windows_local_llm_framework_execution_filter`