LoFP LoFP / legitimate batch scripts and installers may use call with variable assignment, or may delete themselves after a delay using timeout and del. filter by parent process, user or script path as needed.

Techniques

Sample rules

Windows CMD Evasive Patterns Through Native Commands

Description

The following analytic detects cmd.exe being used to evade defenses with nothing but built-in commands, a pattern frequently seen in ClickFix-style social engineering and malware loader activity. Adversaries abuse native cmd.exe features such as call combined with variable assignment to assemble commands piece by piece, hiding the real payload from static inspection and string-based detections. They also chain native utilities such as timeout and del to erase the dropped executable shortly after it has run, which removes evidence and complicates forensic analysis. Because these techniques need no additional tooling, they let attackers blend into routine command shell activity. If confirmed malicious, this could indicate a staged loader concealing its intent or cleaning up after execution.

Detection logic


| tstats `security_content_summariesonly`
  count min(_time) as firstTime
        max(_time) as lastTime

FROM datamodel=Endpoint.Processes WHERE

(
    Processes.process_name=cmd.exe
    OR
    Processes.original_file_name=Cmd.Exe
)
Processes.process IN ("*call *", "*timeout *")
NOT Processes.user IN ("SYSTEM", "*\\SYSTEM")

by Processes.action Processes.dest Processes.original_file_name
   Processes.parent_process Processes.parent_process_exec Processes.parent_process_guid
   Processes.parent_process_id Processes.parent_process_name Processes.parent_process_path
   Processes.process Processes.process_exec Processes.process_guid Processes.process_hash
   Processes.process_id Processes.process_integrity_level Processes.process_name Processes.process_path
   Processes.user Processes.user_id Processes.vendor_product


| `drop_dm_object_name(Processes)`


| eval process_lower=lower(process)


| eval call_set_obfuscation=if(
    like(process_lower, "%call %")
    AND match(process, "(?i)set\\s+[\\x22\\x27]?[\\w\\-\\_]+\\s?\\="), 1, 0)


| eval timeout_self_deletion=if(
    like(process_lower, "%timeout %")
    AND like(process_lower, "%del %")
    AND (like(process_lower, "% /f%") OR like(process_lower, "% /q%"))
    AND like(process_lower, "% exit%"), 1, 0)


| where call_set_obfuscation=1 OR timeout_self_deletion=1


| fields - process_lower


| `security_content_ctime(firstTime)`

| `security_content_ctime(lastTime)`

| `windows_cmd_evasive_patterns_through_native_commands_filter`